.nolist
	#include "ion.inc"	;altered so I don't have to redefine equates
	#include "ti83plus.inc" ;altered to be compatible with tasm not zilog
	.list
	.org progstart-2
	.db $BB,$6D
	xor a
	jr nc,Start
 .db "fastmap",0




NUM_TILES = 5


Objnum:
 .db 1
aclX:
.dw 0
aclY:
.dw 0
velX:
.dw 0
velY:
.dw 0
PlayerX:
.dw 0
Playery:
.dw 0
Jetpack:
 .dw 0
Friction:
 .dw 6
Jump:
 .db 0

gravity:
 .dw 0
timer:
.dw 0

IntSpeed	= 118	;se = 108
FrameRate	= 30
FrameSQ	= FrameRate*FrameRate
DecBit	= 5
Decimal	= 1<<DecBit
Grav		= 450*Decimal/FrameSQ
;JumpPower	= 226
JumpPower	= Decimal*4+16
;jumppower	= sqrt(Pixels)*Decimal
Max_Vel	= 1000*Decimal/FrameRate
Accl		= Decimal/4

.echo "gravity: ",Grav,"  Jump: ",JumpPower

Start:
	di
	ld hl,0
	ld (aclX),hl
	ld (acly),hl
	ld (velX),hl
	ld (velY),hl
	ld (PlayerY),hl
	ld (timer),hl
	xor a
	ld (jump),a

	ld hl,48*decimal
	ld (PlayerX),hl
	ld hl,Grav
	ld (gravity),hl
	call IntOn

loop:
	halt
	ld a,(timer+1)
	or a
	jr z,loop
	xor a
	ld (timer+1),a
	ld hl,gbuf
	ld (hl),0
	ld de,gbuf+1
	ld bc,767
	ldir
	call drawball
	call SafeCopy

	call Physics



	ld a,$ff
	out (1),a
	ld a,$fe
	out (1),a
	ld hl,0
	ld (aclX),hl
	in a,(1)
	bit 1,a
	call z,left
	in a,(1)
	bit 2,a
	call z,right

	ld a,$ff
	out (1),a
	ld a,$bf
	out (1),a
	nop \ nop
	in a,(1)
	bit 5,a
	call z,jumpup
	in a,(1)
	bit 5,a
	call nz,dontjump

	ld a,$ff
	out (1),a
	ld a,$fd
	out (1),a
	nop
	nop
	in a,(1)
	bit 6,a
	jp nz,loop
	call intoff
	ret

;down:
;	ld hl,(viewy)
;	ld de,40*8
;	call cphlde
;	ret nc
;	inc hl
;	ld (viewy),hl
;	ret

dontjump:
	xor a
	ld (jump),a
	ret
jumpup:
	ld a,(jump)
	or a
	jr nz,keepjumping
	ld hl,(playerY)
	ld de,(64-8)*Decimal
	call cphlde
	ret nz
keepjumping:
	ld a,(jump)
	inc a
	ld (jump),a
	cp 7
	ret nc			;if they've jumped for 7 or more frames, get out
	ld hl,-JumpPower
	ld (vely),hl
	ret


left:
	ld a,(jump)
	or a
	ld hl,-accl
	jr z,_shalfl
	ld hl,-(3*accl/4)
_shalfl:
	ld (aclX),hl
	ret
right:
	ld a,(jump)
	or a
	ld hl,accl
	jr z,_shalfr
	ld hl,3*accl/4
_shalfr:
	ld (aclX),hl
	ret




Physics:
	ld hl,(gravity)
	ld de,(Jetpack)
	add hl,de
	ld (aclY),hl

	ld de,(aclX)
	ld a,d
	or e
	jr z,dofriction

	ld hl,(VelX)
	add hl,de
	ld de,Max_Vel
	call cpabshlde
	jr c,skipxmaxvel
	rl h
	ex de,hl
	call c,neghl
skipxmaxvel:
	ld (velx),hl
	jr donedox

dofriction:
	ld hl,(playery)
	ld de,(64-8)*decimal
	call cphlde
	jr nz,donedox

	ld de,(VelX)
	ld a,d
	or e
	jr z,donedox
	ld a,d
	and $80
	ld hl,(friction)
	call z,neghl
	add hl,de
	xor h
	and $80
	jr z,savefricX
	ld hl,0
savefricX:
	ld (VelX),hl
donedox:

	ld de,(aclY)
	ld hl,(VelY)
	add hl,de
	ld (velY),hl

	ld de,(velX)
	ld hl,(playerX)
	add hl,de
	ld de,(96-8)*Decimal
	call cphlde
	jr c,okaysavex
	bit 7,h
	ld hl,(96-8)*Decimal
	jr z,xispos
	ld hl,0
xispos:
	ld de,0
	ld (velx),de
	ld (aclx),de
okaysavex:
	ld (playerx),hl

	ld de,(velY)
	ld hl,(playerY)
	add hl,de
	ld de,(64-8)*Decimal
	call cphlde
	jr c,okaysavey
	bit 7,h
	ld hl,(64-8)*Decimal
	jr z,yispos
	xor a
	ld h,a \ ld l,a
	ld (jump),a		;reset jump when they hit the ground again.
yispos:
	ld de,0
	ld (vely),de
	ld (acly),de
okaysavey:
	ld (playerY),hl

	ret



cphlde:
	push hl
	or a
	sbc hl,de
	pop hl
	ret


cpabshlde:
	push hl
	bit 7,h
	call nz,neghl
	or a
	sbc hl,de
	pop hl
	ret

neghl:
	push af
	ld a,h
	cpl
	ld h,a
	ld a,l
	cpl
	ld l,a
	inc hl
	pop af
	ret

;HLnodec:
;	push bc
;	ld b,8-decbit
;	inc b
;	dec b
;	jr z,doneHLnodec
;decloop:
;	rl l
;	rl h
;	djnz 	decloop
;doneHLnodec:
;	pop bc
;	ret

drawball:
	ld hl,(playerx)
	rl l
	rl h
	rl l
	rl h
	rl l
	rl h
	ld a,h
	cp 96-7
	ret nc
	ld c,a
	ld hl,(playery)
	rl l
	rl h
	rl l
	rl h
	rl l
	rl h
	ld a,h
	cp 64-7
	ret nc	
	ld l,a
	ld a,c
	ld ix,ball
	ld b,8
	jp ionputsprite



IntOn:
	di
	ld hl,$8b00
	ld (hl),$8a
	ld de,$8b01
	ld bc,256
	ldir
	ld a,$8b
	ld i,a
	ld hl,$8a8a
	ld de,interrupt
	ld (hl),$c3
	inc hl
	ld (hl),e
	inc hl
	ld (hl),d

	ld a,6
	out (4),a       ;set frequency
	ld a,8 
	out (3),a       ;resets any waiting interrupts 
	ld a,10 
	out (3),a       ;resets any waiting interrupts 


	im 2
	ei
	ret

Interrupt:
	ex af,af'
	exx
	ld hl,(timer)
	ld de,0+(256*FrameRate)/IntSpeed
	add hl,de
	ld (timer),hl
	ld a,6
	out (4),a       ;set frequency
	ld a,8 
	out (3),a       ;resets any waiting interrupts 
	ld a,10 
	out (3),a       ;sets the normal interrupt timer 
	ex af,af'
	exx
	ei
	reti

IntOff:
	di
	ld a,6
	out (4),a       ;set frequency
	ld a,8 
	out (3),a       ;resets any waiting interrupts 
	ld a,11
	out (3),a       ;sets the normal interrupt timer 
	im 1
	ei
	ret



SafeCopy:	
	ld c,$10
	ld a,$80
setrow:
	in f,(c)
	jp m,setrow
	out ($10),a
	ld hl,gbuf
	ld de,12
	ld a,$20
col:
	in f,(c)
	jp m,col
	out ($10),a
	push af
	ld b,64
row:
	ld a,(hl)
rowwait:
	in f,(c)
	jp m,rowwait
	out ($11),a
	add hl,de
	djnz row
	pop af
	dec h
	dec h
	dec h
	inc hl
	inc a
	cp $2c
	jp nz,col
	ret

Ball:
 .db $3C,$7E,$FF,$FF,$FF,$FF,$7E,$3C

.end